Tipps für:

Gruppenrichtlinien

Partnerseiten

Virgis-Dreambabys
WinSupportForum.de
Freeware-base
 Compuserve Login Skript

Compuserve Login Skript

Gültig für: Windows 95 | Windows 98 | Windows ME | Windows NT | Windows 2000 | Windows XP


icons/internet.png

;-------------- Anfang

proc main

set port databits 7

set port parity even

delay 2

transmit "<cr>"

waitfor "ame:"

transmit "CIS<cr>"

waitfor "ID:"

transmit $USERID

transmit "/GO:PPPCONNECT<cr>"

waitfor "word:"

transmit $PASSWORD

transmit "<cr>"

waitfor "PPP"

set port databits 8

set port parity none

endproc

;-------------- Ende

 

Skript für eine RAS-Verbindung zu CompuServe.

 

Die Adressen:

149.174.211.5     DNS-Adresse

149.174.213.5     DNS-Adresse

 

Skript:

 

;***********************************************

;* Login-Skript für die Einwahl ins

;* Internet über Datex-J und Compuserve

;* (Telefonnummer in Deutschland: 01910)

;***********************************************

;* Version 2.1 (c) 1996 Wolfgang Wirth

;* Letzte Änderung am 22:06 19.09.96

;* E-Mail : 71333.1421@compuserve.com

;***********************************************

 

proc main

 

string ErrStr

 

;***********************************************

;*** Dial-up Port auf 8n1 setzen

set port databits 8

set port parity none

 

;***********************************************

;*** Hier befinden wir uns auf der T-Online

; Startseite. Als erstes muss ein Dezimalpunkt

; mit <CR> geschickt werden, um auf einen

; "Text-Dekoder" hinzuweisen.

;

delay 3

transmit ".^M"

 

;***********************************************

;*** Hier befinden wir uns auf der T-Online

;      Login-Seite. Wenn das Wort "kennung"

;       erscheint, wird die Compuserve-

;       Kennung geschickt. Ein <CR> ist nicht

;       nötig, da die Seite automatisch nach

;      der Kennungseingabe wechselt.

;

waitfor     "kennung" until 30

if !$SUCCESS then

     Errstr="Datex-J-Kennung"

     goto fehler

endif

transmit "000255975978"

 

;***********************************************

;*** Hier befinden wir uns auf der Compuserve

;      Login-Seite. Punkt "2" steht für Login von

;       Mitgliedern. Ein <CR> wird geschickt, um

;       auch die nachfolgende Seite zu quittieren.

;

transmit "2^M"

 

;***********************************************

;*** Datex-J haben wir jetzt passiert. Jetzt stehen

;       wir bei Compuserve auf der Matte. Das System

;       fragt hier nach dem Host-Namen, der in unserem

;       Fall "CIS" lautet und mit einem <CR> abgeschlos-

;       sen werden muss.

;

waitfor     "Host Name:" until 30

if !$SUCCESS then

     Errstr="Compuserve Host-Name"

     goto fehler

endif

transmit "CIS^M"

 

;***********************************************

;*** Jetzt muss unsere CIS-Anwenderkennung übermittelt

;      werden. Es wird die Systemvariable $USERID benutzt,

;       die den entsprechenden Eintrag aus dem Anwahl-

;       Dialog enthält. Die ID wird mit dem Parameter

;       RAW gesendet, damit keine Steuer- bzw. So nder-

;       zeichenübersetzung auf dem Host stattfindet.

;       Das Kommando für einen PPP-Connect kann man gleich

;       an die ID mitanhängen. Das ganze muss mit einem <CR>

;       abgeschlossen werden.

;

waitfor     "User ID:" until 30

if !$SUCCESS then

     Errstr="Compuserve Anwenderkennung"

     goto fehler

endif

transmit $USERID, raw

transmit "/go:pppconnect^M"

 

;***********************************************

;*** Mit der Übermittlung des Passwortes wird das Login

;       abgeschlossen. Es wird die Systemvariable $PASSWORD

;       benutzt, die den entsprechenden Eintrag aus dem

;       Anwahl-Dialog enthält. Das Passwort wird mit dem

;       Parameter RAW gesendet, damit keine Steuer- bzw.

;       Sonderzeichenübersetzung auf dem Host stattfindet.

;       Das ganze muss mit einem <CR> abgeschlossen werden.

;

waitfor     "Password:" until 30

if !$SUCCESS then

     Errstr="Compuserve Anwenderpasswort"

     goto fehler

endif

transmit $PASSWORD, raw

transmit "^M"

 

;***********************************************

;*** Damit ist das Login abgeschlossen. Wir warten

;       jetzt nur noch auf eine kleine Quittierung vom

;       System

;

waitfor     "One moment please" until 60

 

;***********************************************

;*** Hurra - Wir stehen im Internet! Das Skript endet

;       hier und das Login-Fenster schließt sich.

;

goto ende

 

;***********************************************

;*** Mist! Ein Fehler ist aufgetreten.

;       Der Grund wird über Modem-Echo ins

;      Verbindungsfenster geleitet

;

fehler:

transmit "+++"           ; Modem in Kommandomodus schicken

delay 3            ; Kommandomoduszwangspause

waitfor     "ok", "0" until 5      ; Auf OK oder 0 warten

transmit "ate1^M"       ; Modem: Echo ein

waitfor     "ok", "0" until 2      ; Auf OK oder 0 warten

; Fehlerinformation senden (kommt als Echo ins Fenster)

transmit "*** VERBINDUNGSFEHLER:^M^J"

transmit "*** " + ErrStr + " wurde nicht angefordert^M^J"

transmit "*** Das Skript wird daher abgebrochen.^M^J"

delay 3               ; Anwender Zeit zum Lesen lassen

transmit "ath0^M"     ; Modem soll auflegen

delay 10          ; Zeit für System zum Gen. des

halt                    ; Meldungsfensters

 

;***********************************************

ende:

 

endproc


WinFAQ: Startseite | WinFAQ: HTMLMenü | WinFAQ: Java Version


Der Tipp enthält einen Fehler oder Sie haben noch eine Ergänzung dafür? Schreiben Sie uns über die Feedback-Seite an: Feedback-Formular

Impressum | Datenschutz

 

URL: http://www.winfaq.de/faq_html/Content/tip0000/onlinefaq.php?h=tip0088.htm

WinFAQ ® Version 9.01 Copyright © 1996/2016 by Frank Ullrich

Hauptmenü

Registry System Wizard

Über WinFAQ